IV. Probabilités continues et rappels d’analyse

Clear[a,b]

RandomReal[1,WorkingPrecision->100]

Loi uniforme sur [0,1]

S:=RandomReal[1]
Table[S,{20}]

La probabilité P(  S=(1/2)) est évidemment 0, mais la probabilité que 
P(  S≤(1/2))=1/2 et plus généralement P(  S≤x)=x pour 0≤x≤1. 
On peut donc dire que la fonction de répartition de la variable aléatoire continue uniforme sur [0,1] est la fonction 
	- F(x)=0 si x<0
	- F(x)=x si 0≤x≤1
	- F(x)=1 si x≥1

Count[Table[S,{10000}],x_/;.1≤x≤.4]/100//N

Table[S,{20}]

Une expérience

On tire n=2 fois un réel entre 0 et 1   et on calcule la moyenne (Subscript[S, n]) des nombres obtenus.

Clear[S]
S:=(RandomReal[1]+RandomReal[1])/2
S

Table[S,{10}]

S est une variable aléatoire qui peut prendre n’importe quelle valeur entre 0 et 1. Attention on a toujours P[S=x]=0.

Question.  Pour dx petit, on peut calculer  la fonction  P(x≤S≤x+dx)

Pour cela, on évalue k
 tirages de S

k=100000;
tirages=Table[S, {k}];
m=50;
ListPlot[Table[{i/m,Length[Select[tirages,((i-1)/m<#&&#≤i/m)&]]/k},{i,1,m}]]

Grid[{
{"Valeurs",
 Histogram[tirages, {.2}],
   Histogram[tirages, {.005}]},
  {"Frequences",
 Histogram[tirages, {.2}, "Probability"],
   Histogram[tirages, {.005}, "Probability"]},
  {"Densité", 
Histogram[tirages, {.2},"PDF"],
   Histogram[tirages, {.005}, "PDF"]}}, Frame -> All]

Question.   Que vaut  la fonction de densité

La fonction de densité f(x) semble être

f[x_] := 2 - 4 Abs[x - 1/2]
Plot[f[x], {x, 0, 1}]

q

On a bien (∫_0^1)f(x)dx=1

Integrate[f[t],{t,0,1}]

Question.   Calculer la fonction de répartition

La fonction de répartition F(x)  est  F(x)=P(X≤x)=(∫_0^x)f(x)dx

Ici, on a

f[x_]:=2-4Abs[x-1/2]
F1[x_]:=Assuming[x>0&&x≤1/2, Integrate[f[t],{t,0,x}]]
F2[x_]:=Assuming[x>1/2&&x≤1, Integrate[f[t],{t,0,x}]]
Plot[If[x<1/2,F1[x],F2[x]],{x,0,1}]

Loi de probabilité continue

Définitions. On dit qu’une variable aléatoire X suit la loi de densité  f lorsque 
	• f est une fonction de ℝ dans (SuperPlus[ℝ])
	• (∫_(-∞)^(+∞))f(t)dt=1
La fonction de répartition de X est alors
	•F(x)=(∫_(-∞)^x)f(t)dt
La probabilité P(a≤X≤b) est alors donnée par
	• P(a≤X≤b)=F(b)-F(a)=(∫_a^b)f(t)dt

Exemple. La loi uniforme sur [a,b] a pour densité la fonction
	f(x)=0 si x<a ou x>b
	f(x)= (1/(b-a)) si a≤x≤b

Propriétés. 
La fonction de répartition F d’une variable aléatoire X de densité f satisfait les propriétés
	• f est croissante
	•  ∀ x ∈ ℝ, 0≤F(x)≤1
	• (Underscript[lim , t->-∞])F(t) = 0
	• (Underscript[lim , t->+∞])F(t) = 1
	• (∂/(∂x))F(x)=f(x)

Moments d’une variable aléatoire

L’espérance d’une variable aléatoire X de densité f est E(X)=(∫_(-∞)^(+∞))t f(t)dt
La variance d’une variable aléatoire X de densité f est Var(X)=E((X^2))-((E(X))^2)
Le moment d’ordre m  d’une variable aléatoire X de densité f est  E((X^m))=(∫_(-∞)^(+∞))(t^m) f(t)dt
Le moment centré d’ordre m  d’une variable aléatoire X de densité f est  E((((X-E(X)))^m))=(∫_(-∞)^(+∞))(((t-E(X)))^m) f(t)dt

Exemple. 
	• L’espérance de la loi uniforme sur [a,b] est
		E(X) = (∫_a^b)t (1/(b-a))dt=(((b^2)-(a^2))/2)(1/(b-a))=((a+b)/2)
	•Le moment d’ordre 2  de la loi uniforme sur [a,b] est
		E((X^2)) = (∫_a^b)(t^2) (1/(b-a))dt=(((b^3)-(a^3))/3)(1/(b-a))=(((a^2)+ab+(b^2))/3)
	• La variance  de la loi uniforme sur [a,b] est
		E((X^2))-((E(X))^2)=(((a^2)+ab+(b^2))/3)-(((((a+b)/2)))^2)=((((b-a))^2)/12)

f[t_]:=1/(b-a)
Integrate[f[t],{t,a,b}]
EX=Simplify[Integrate[t f[t],{t,a,b}]]
EX2=Simplify[Integrate[t^2 f[t],{t,a,b}]]
VX=Simplify[EX2-EX^2]

Loi exponentielle

La loi exponentielle est la version continue de la loi géométrique. Elle intervient surtout dans les problèmes de file d’attente.

Définition. On appelle loi exponentielle de paramètre λ, la variable aléatoire notée X∼ℰ(λ) dont la fonction de densité est 
		f(x)=λ (e^(-λx))(Subscript[1, {x≥0}])

Remarques. 
	• C’est bien la densité d’une probabilité car (∫_0^(+∞))λ (e^(-λ t))dt=1
	• Son espérance est (∫_0^(+∞))λ t (e^(-λ t))dt=(1/λ)
	• Sa variance est (∫_0^(+∞))λ (((t-(1/λ)))^2) (e^(-λ t))dt=(1/(λ^2))
	• La fonction de répartition de la loi exponentielle est 
		F(x)=(∫_0^x)λ (e^(-λ t))dt=1-(e^(-λx))

f[t_]:=λ Exp[-λ t]
Integrate[f[t],{t,0,+Infinity}]
EX=Simplify[Integrate[t f[t],{t,0,+Infinity}]]
EX2=Simplify[Integrate[t^2 f[t],{t,0,+Infinity}]]
VX=Simplify[EX2-EX^2]
Integrate[f[t],{t,0,x}]

Rappels d’analyse

Dérivation et intégration

Dérivation par partie

Somme de variables aléatoires continues indépendantes

Soient X et Y des variable aléatoires indépendantes de fonction de densité f et g. Alors la fonction de densité de la variable aléatoire Z=X+Y est la convolution f⋆g définie par 
		 f⋆g(z)=(∫_(-∞)^(+∞))f(t)g(z-t)dt

P(Z≤t)=P(Z≤t ⋂ X∈]-∞,+∞[ )
	=(∫_(-∞)^t)(∫_(-∞)^(+∞))h(z,x)dzdx
	=(∫_(-∞)^t)(∫_(-∞)^(+∞))h(z|x)f(x)dzdx
	=(∫_(-∞)^t)(∫_(-∞)^(+∞))g(z-x)f(x)dzdx

Exercice. Calculer la densité de la  somme de deux variables aléatoires uniformes sur [0,1].

Densité de la  somme de deux variables aléatoires uniformes sur [0,1]

Ici, la fonction de densité de la variable aléatoire Z=X+Y est la convolution f⋆f définie par  
	• f(x)=(Subscript[1, x∈[0,1]])
	• f⋆f(x)=(∫_(-∞)^(+∞hj))(Subscript[1, x∈[0,1]])(Subscript[1, x-t ∈[0,1]])dt

0≤x-t≤1 ⟺x-1≤t≤x

Manipulate[Plot[{UnitBox[t],If[x-1≤t≤x,1,0]},{t,0,1},Filling->Axis],{x,0,1}]

On a alors 4 cas à envisager,
	• Si x<0, alors  f⋆f(x)=0
	• Si 0≤x<1, alors  f⋆f(x)=(∫_0^x)1dt=x
	• Si 1≤x<2, alors  f⋆f(x)=(∫_(x-1)^1)1dt=2-x
	• Si x≥2, alors  f⋆f(x)=0

f[x_]:=If[x<0|| x>1,0,1]
g[x_]:=Convolve[f[t],f[t],t,x]

Plot[g[x],{x,-2,3}]

Quelques inégalités célèbres

Inegalité de Markov
Soit X une variable aléatoire à densité admettant un moment d’ordre m, alors, pour tout réel t>0, on a 
		P(|X|≥t)≤((E(|X((|)^m)))/(t^m))
En particulier, pour m=1, on a  
		P(|X|≥t)≤((E(|X|))/t)

Preuve (pour m=1) : 
t P(X≥t)=t(∫_t^(+∞))f(x)dx=(∫_t^(+∞))t f(x)dx ≤(∫_t^(+∞))x f(x)dx≤(∫_0^(+∞))x f(x)dx=E(X)

Inegalité de Tchebychev
Soit X une variable aléatoire à densité admettant une variance, alors, pour tout réel t>0, on a 
		P(|X-E(X)|≥t)≤((Var(X))/(t^2))

Preuve  : On utilise l’inégalité de Markov sur (((X-E(X)))^2)

Exemples de loi de probabilité continue

On peut remarquer facilement que toute fonction positive et intégrable peut générer facilement une fonction de densité. Prenons par exemple  la fonction 
x↦(x^2) entre -2 et 2, et nulle ailleurs. Si l’on note a son intégrale a=(∫_(-∞)^∞)f(x)dx

f[x_]:=If[Abs[x]>2,0,x^2]
Plot[f[x],{x,-4,4}]
a=Integrate[f[x],{x,-Infinity,Infinity}]
g[x_]:=f[x]/a
G[x_]:=Integrate[g[t],{t,-Infinity,x}]
Plot[G[x],{x,-4,4}]

f[x_]:=If[Abs[x]>2,0,x^2]
esperance=Integrate[x f[x]/a,{x,-Infinity,Infinity}]
variance=Integrate[x^2 f[x]/a,{x,-Infinity,Infinity}]-esperance^2